Scaleway et Terraform

Maintenant que nous avons configuré notre provider, nous allons nous amuser à déployer un petit conteneur WordPress, et pour cela nous allons commencer par créer notre base de données  !

variable "region" { 
  type = string 
  description = "La région dans laquelle nous allons créer nos ressources"  
  default = "fr-par" 
} 

variable "zone" { 
  type = string description = "La zone de la région dans laquelle nous allons créer nos ressources" default = "fr-par-1" 
} 

terraform { 
  required_providers { 
    scaleway = { 
      source = "scaleway/scaleway" 
    } 
  } 
  required_version = ">= 0.13" 
} 

provider "scaleway" { 
  region = var.region 
  zone = var.zone 
}

Managed Datadase

Nous allons commencer par créer un fichier dédié à cette ressource, disons mysql.tf.

D’abord nous allons créer quelques variables qui vont nous être utiles, comme le nom de la base de données et notre nom d’utilisateur pour celle-là.

Nous allons utiliser une ressource bien utile de Terraform pour générer un mot de passe complexe pour notre utilisateur de base de données. Nous nous assurons au passage de respecter les conditions imposées par Scaleway quant à la politique de mot de passe.

Ensuite nous allons créer notre instance de serveur de base de données. Les paramètres utilisés ici correspondent, bien sûr, à des exemples pour un environnement de développement.

variable "wp_username" {
  type        = string
  default     = "wp-admin"
}


variable "wp_db_name" {
  type        = string
  default     = "wordpress"
}

resource "random_password" "wp_sql_pwd_db" {
  length  = 16
  special = true
  min_lower = 1
  min_numeric = 1
  min_special = 1
  min_upper = 1
}

resource "scaleway_rdb_instance" "wp_sql" {
  name           = "wp-mysql"
  node_type      = "DB-DEV-S"
  engine         = "MySQL-8"
  is_ha_cluster  = true
  disable_backup = true
  user_name      = var.wp_username
  password       = random_password.wp_sql_pwd_db.result
}

variable "wp_username" {
  type        = string
  default     = "wp-admin"
}

variable "wp_db_name" {
  type        = string
  default     = "wordpress"
}

resource "random_password" "wp_sql_pwd_db" {
  length  = 16
  special = true
  min_lower = 1
  min_numeric = 1
  min_special = 1
  min_upper = 1
}

resource "scaleway_rdb_instance" "wp_sql" {
  name           = "wp-mysql"
  node_type      = "DB-DEV-S"
  engine         = "MySQL-8"
  is_ha_cluster  = true
  disable_backup = true
  user_name      = var.wp_username
  password       = random_password.wp_sql_pwd_db.result
}

resource "scaleway_rdb_database" "wp_sql_db" {
  instance_id    = scaleway_rdb_instance.wp_sql.id
  name           = var.wp_db_name
}

Nous n’avons qu’à récupérer l’id de notre instance fraîchement créée et lui donner le nom que nous souhaitons.
Et voilà ! Nous avons écrit le code représentant notre serveur de base de données.
Passons maintenant à notre WordPress.

 

Serverless Container

Scaleway propose différentes solutions pour déployer nos applications, du Kubernetes, des serverless functions et containers ou encore des machines virtuelles. Ici nous allons utiliser les serverless containers. Nous allons avoir besoin uniquement de deux ressources : un namespace dans lequel nous allons déployer notre 2e ressource, notre conteneur. Ajoutons un nouveau fichier, wordpress.tf :

variable "container_name" {
  type        = string
  default     = "wordpress-example"
}

resource "scaleway_container_namespace" "wp_namespace" {
  name        = "wp-namespace"
  description = "namespace dédié au conteneur wordpress-example"
}

resource "scaleway_container" "wp_container" {
    name = var.container_name
    description = "wordpress container"
    namespace_id = scaleway_container_namespace.wp_namespace.id
    registry_image = "bitnami/wordpress:latest"
    port = 3000
    cpu_limit = 1120
    memory_limit = 2048
    min_scale = 1
    max_scale = 2
    timeout = 600
    max_concurrency = 10
    protocol = "h2c"
    deploy = true

    environment_variables = {
        "WORDPRESS_DEBUG" = "1" 
    }
    secret_environment_variables = {
      "WORDPRESS_DATABASE_HOST" = scaleway_rdb_instance.wp_sql.endpoint_ip
      "WORDPRESS_DATABASE_PORT_NUMBER" = scaleway_rdb_instance.wp_sql.endpoint_port
      "WORDPRESS_DATABASE_NAME" = var.wp_db_name
      "WORDPRESS_DATABASE_USER" = var.wp_username
      "WORDPRESS_DATABASE_PASSWORD" = random_password.wp_sql_pwd_db.result
    }
    depends_on = [
      scaleway_rdb_instance.wp_sql,
      random_password.wp_sql_pwd_db
    ]
}

Le provider Scaleway facilite la configuration de ce conteneur. Vous retrouvez ici tous les paramètres existants. Nous pouvons retrouver des classiques comme, bien sûr, l’image de notre conteneur, les ressources allouées, le scaling, etc. 

Mais un paramètre a attiré mon attention, le « secret_environment_variables ». Celui-ci nous permet de passer facilement des secrets qui seront chargés en variables, ce qui est très utile niveau sécurité ! 

 

A l’action !

 

Nous y voilà, nous avons terminé de décrire notre infrastructure, il ne nous reste plus qu’à la créer !
Je vais créer un fichier de variables, uncommited.tfvars.

wp_username = "test"
wp_db_name = "dbtest"
access_key = "xxx"
secret_key = "xxx"
project_id = "xxx"
organization_id = "xxx"

Il ne nous reste plus qu’à appliquer nos fichiers Terraform

Après avoir accepté le plan de Terraform, il ne vous reste plus qu’à patienter et regarder vos ressources se créer.